|
123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313 |
- // dependency: https://github.com/revarbat/BOSL
- use <BOSL/transforms.scad>
- //use <BOSL/metric_screws.scad>
- use <BOSL/masks.scad>
-
- use <holodisk_spec.scad>
- use <tape_spool.scad>
- use <anim.scad>
-
- module holodisk_frame() {
- size = get_holodisk_size();
- disk_size = get_holodisk_size();
- holodisk_size = get_holodisk_size();
- width=size.x;
- depth=size.y;
- height=size.z;
-
- wall=3;
- plate=3;
- top_rim=2;
- bolt_headtype="hex";
- front_body_depth=12;
- front_body_bolt_offset=8;
- back_bumpers_radius=5;
- back_bumpers_bolt_size=3;
- tape_height=5;
- tape_thickness=0.2;
- spool_tape_tolerance=1;
- spool_inner_height=tape_height+spool_tape_tolerance;
- spool_inner_radius=4;
- spool_outer_radius=18;
- spool_plate_height=2;
- spool_plate_holes=3;
- spool_plate_hole_angle=360/spool_plate_holes * 0.5;
- spool_plate_hole_inner_rim=1;
- spool_plate_hole_outer_rim=4;
- spool_slit_depth=0.8;
- spool1_depth=disk_size.y*0.77;
- spool2_depth=disk_size.y*0.40;
- spool3_depth=(spool1_depth+spool2_depth)/2;
- spool4_depth=disk_size.y*0.16;
- main_spools_x=disk_size.x*0.45;
- aux_spools_right_x=main_spools_x + spool_outer_radius + 1;
- aux_spools_left_x=main_spools_x - 13;
- middle_spool_in_r=2;
- middle_spool_out_r=7;
- aux_spool_plate_hole_inner_rim=2;
- aux_spool_plate_hole_outer_rim=2;
- spindle_diam=2;
- spindle_diam_tolerance=0.2;
- tape_z=plate+spool_plate_height;
-
- tr=top_rim;
- tc=tr*1.5;
- fbd=front_body_depth;
- bbr=back_bumpers_radius;
-
- walls_height=height-plate*2;
-
- module back_bumpers() {
- module bumper() { back_half() circle(r=bbr); }
- back(depth) {
- right(bbr) bumper();
- right(width-bbr) bumper();
- }
- }
-
- module bolt() { metric_bolt(size=back_bumpers_bolt_size, headtype=bolt_headtype, l=height, pitch=0); }
- module nut() { metric_nut(size=back_bumpers_bolt_size, pitch=0); }
-
- module back_bolts() {
- back(depth) {
- right(bbr) {
- up(height) bolt();
- nut();
- }
- right(width-bbr) {
- up(height) bolt();
- nut();
- }
- }
- }
-
- module front_bolts() {
- bolt_offset=front_body_bolt_offset;
- back(front_body_depth/2) {
- right(bolt_offset) {
- up(height) bolt();
- nut();
- }
- right(width-bolt_offset) {
- up(height) bolt();
- nut();
- }
- }
- }
-
- module top_cover() {
- up(height-plate) linear_extrude(height=plate) {
- back_bumpers();
- polygon(points=[
- // frame
- [0, 0], [0, depth],
- [width, depth], [width, 0],
- // window
- [tr, tr+fbd], [tr, depth-tr-tc], [tr+tc, depth-tr],
- [width-tr-tc, depth-tr], [width-tr, depth-tr-tc], [width-tr, tr+fbd]
- ],
- paths=[
- [0,1,2,3], [4,5,6,7,8,9]
- ]);
- }
- }
-
- module walls() {
- difference() {
- up(plate) linear_extrude(height=walls_height) {
- //back_bumpers();
- shell2d(thickness=-wall) {
- square([width, depth]);
- }
- }
- translate(get_holodisk_laserwindow_pos_center()) cube(get_holodisk_laserwindow_size(), center=true);
- }
- }
-
- module front_plates() {
- th = get_holodisk_front_plate_thickness();
- slide_pos = get_holodisk_slide_pos();
- offset=4.5;
- plate_len_side=slide_pos.y - offset/2;
- plate_len_left=plate_len_side/2;
- plate_len_right=plate_len_side + 5;
- // front
- fwd(th) left(th) up(offset) {
- cube([plate_len_left + th*2, th, height - offset*2]);
- }
- fwd(th) right(width-plate_len_right-th) up(offset) {
- cube([plate_len_right + th*2, th, height - offset*2]);
- }
- // left
- fwd(th) left(th) up(offset) {
- cube([th, plate_len_side, height - offset*2]);
- }
- // right
- fwd(th) right(width) up(offset) {
- cube([th, plate_len_side, height - offset*2]);
- }
- }
-
- module slides() {
- slide_size = get_holodisk_slide_size();
- slide_pos = get_holodisk_slide_pos();
- slide_plate_size = [0.1, slide_size.y, slide_size.z];
- sliding_size = get_holodisk_slide_sliding_size();
- sliding_pos = get_holodisk_slide_sliding_pos();
-
- module slide() {
- hull() {
- translate(sliding_pos) cube(sliding_size);
- translate(slide_pos) cube(slide_plate_size);
- }
- }
-
- module slider() {
- slider_size = get_holodisk_slide_slider_size();
- slider_pos = get_holodisk_slide_slider_pos();
- slider_plate_size = [0.1, slider_size.y, slider_size.z];
- slider_top_size = [slider_size.x, slider_size.y, sliding_size.z];
- hull() {
- up((slider_size.z-sliding_size.z)/2) translate(slider_pos) cube(slider_top_size);
- translate(slider_pos) cube(slider_plate_size);
- }
- }
-
- module slider_anim() {
- back(anim(1,2)*get_holodisk_slide_slider_travel()) // anim insert
- fwd(anim(5,6)*get_holodisk_slide_slider_travel()) // anim remove
- slider();
- }
-
- right(get_holodisk_size().x) {
- slide();
- slider_anim();
- }
- scale([-1,1,1]) {
- slide();
- slider_anim();
- }
-
- right(get_holodisk_laserwindow_pos_center().x) zrot(-90) {
- scale([1, 0.7, 1]) {
- slider();
- }
- }
- }
-
- module sliding_cover() {
- thickness=1;
- overlap=2;
- cover_size=[
- get_holodisk_size().x+thickness*2,
- get_holodisk_laser_cutout_size().y+overlap*2,
- thickness
- ];
- cover_posc=[
- get_holodisk_laser_cutout_pos_center().x,
- get_holodisk_laser_cutout_pos_center().y,
- cover_size.z/2
- ];
- cover_side_size=[thickness, cover_size.y, get_holodisk_slide_slider_pos().z];
- cover_side_left_posd=[-cover_size.x/2+thickness/2, 0, cover_side_size.z/2];
- cover_side_right_posd=[cover_size.x/2-thickness/2, 0, cover_side_size.z/2];
- translate(cover_posc) {
- cube(cover_size, center=true);
- translate(cover_side_left_posd) cube(cover_side_size, center=true);
- translate(cover_side_right_posd) cube(cover_side_size, center=true);
- }
- }
-
- module sliding_cover_anim() {
- back(anim(1,2)*get_holodisk_slide_slider_travel()) // anim insert
- fwd(anim(5,6)*get_holodisk_slide_slider_travel()) // anim remove
- sliding_cover();
- }
-
- module laserwindow_door() {
- door_size = [
- get_holodisk_laserwindow_size().x,
- 1,
- get_holodisk_laserwindow_size().z
- ];
- door_pos = [
- get_holodisk_laserwindow_pos_center().x,
- get_holodisk_laserwindow_pos_center().y + door_size.y/2,
- get_holodisk_laserwindow_pos_center().z
- ];
-
- translate(door_pos) scale(0.98) down(door_size.z/2) xrot(anim(1,2)*-90) xrot(anim(6,7)*90) up(door_size.z/2) cube(door_size, center=true);
- }
-
- module bottom_cover() {
- difference() {
- linear_extrude(height=plate) {
- back_bumpers();
- square([width, depth]);
- }
- // laser cutout
- down(0.1) translate(get_holodisk_laser_cutout_pos()) cube(get_holodisk_laser_cutout_size());
- // sliding cover
- sliding_cover();
- back(get_holodisk_slide_slider_travel()*0.5) sliding_cover();
- back(get_holodisk_slide_slider_travel()) sliding_cover();
- // spool spindles
- translate(get_holodisk_spool1_socket_pos_center()) spindle(h=height, d=get_holodisk_spools_spindle_diam());
- translate(get_holodisk_spool2_socket_pos_center()) spindle(h=height, d=get_holodisk_spools_spindle_diam());
- }
- }
-
- {
- overlap=1;
- rails_size = [
- get_holodisk_laserwindow_size().x * 2 + overlap*2,
- 1,
- walls_height
- ];
- rail_size = [rails_size.x, rails_size.y, 2];
- rails_pos = [get_holodisk_laserwindow_pos().x - rails_size.x/2,
- -rails_size.y, plate];
- rail1_pos = [rails_pos.x, rails_pos.y, rails_pos.z];
- rail2_pos = [rails_pos.x, rails_pos.y, rails_pos.z + rails_size.z - rail_size.z];
-
- module laserwindow_slider_rails() {
- translate(rail1_pos) cube(rail_size);
- translate(rail2_pos) cube(rail_size);
- }
-
- module laserwindow_slider_cover() {
- cover_size=[
- get_holodisk_laserwindow_size().x,
- get_holodisk_slide_slider_size().x,
- get_holodisk_slide_slider_size().z
- ];
- cover_plate=[cover_size.x, rail_size.y, cover_size.z];
- cover_top=[cover_size.x - overlap, cover_size.y, cover_size.z - overlap];
- /*cover_pos=[rails_pos.x+overlap, rails_pos.y + rails_size.y, rails_pos.z];*/
- cover_pos=[get_holodisk_laserwindow_pos().x, rails_pos.y + rails_size.y, rails_pos.z];
- left(anim(0,1)*get_holodisk_laserwindow_size().x)
- right(anim(len(get_anim_keys())-2,len(get_anim_keys())-1)*get_holodisk_laserwindow_size().x)
- translate(cover_pos)
- hull() {
- fwd(cover_plate.y) cube(cover_plate);
- right(overlap/2) fwd(cover_top.y) up((cover_plate.z-cover_top.z)/2) cube(cover_top);
- }
- }
-
- color("red") laserwindow_slider_rails();
- color("red") laserwindow_slider_cover();
- }
-
- color("SaddleBrown") top_cover();
- color("grey") walls();
- color("gold") laserwindow_door();
- color("Silver") slides();
- color("Silver") sliding_cover_anim();
- color("SaddleBrown") bottom_cover();
- color("SaddleBrown") front_plates();
- //color("silver") back_bolts();
- //color("silver") front_bolts();
- }
-
- // test
- holodisk_frame();
|